Useful macros for warriors

Macros
General guides
Macros Beginners Guide Making a macro Macro conditionals Macro commands Category:Macros
Useful macros by class

Three-Spells-in-One-Button Tanking macro

Use this spamable macro for space saving and easy tanking:

#showtooltip
/castrandom [equipped:shields] Shield Slam, Revenge; Revenge
/cast [equipped:shields] Shield Block

NOTE: Works with duel wielding.

NOTE: castsequence did not use Revenge enough, due to lack of rage for a Shield Slam, so castrandom works much better.

Can be used in conjunction with a simple Devastate macro:

#showtooltip
/cast Devastate
//cast !Heroic Strike
/startattack

NOTE: Remove a '/' from Heroic Strike to cast it as well. Useful in endless-rage situations.

NOTE: can be improved with "/castrandom [stance:1] Overpower, Devastate; Devastate"

Retaliation, Shield Wall or Recklessness

One macro to make one button handle your special long cooldown moves. When using Retaliation it is often advisable to switch to defensive stance and use challenging shout.

/cast [stance:1] Retaliation; [stance:2,equipped:Shields] Shield Wall; [stance:2,noequipped:Shields] Battle Stance; [stance:3] Recklessness
/stopcasting
/cast [stance:1,modifier:ctrl] Defensive Stance

Shield Bash or Pummel

Will use the Shield Bash ability if you have a shield and are in the correct stance, otherwise will place you in Berserker Stance and use Pummel.

/cast [stance:1/2,noequipped:Shields] Berserker Stance; [stance:1/2,equipped:Shields] Shield Bash; [stance:3] Pummel

This can be combined with Spell Reflection. If you are out of range to Shield Bash or Shield Bash is on cooldown you try to use Spell Reflection with this macro. Since Spell Reflection does not work on Berserker Stance and you are clearly meeting a caster if you use it I have made it swich from Berserker to Battle Stance if you have a shield equiped.

/cast [nostance:3,equipped:Shields] Shield Bash; [stance:3] Pummel; Berserker Stance;

All in one charge

If you are in combat, this macro will make sure that you are in berserker stance, then cast intercept. If you are not in combat, you will be placed into battle stance, then charge. The icon will also change to indicate which skill will be used. Either way, if you are using a shield, you will be placed in defensive stance. Delete the last line if you don't want to be placed in defensive stance.

#show [combat] Intercept; Charge
/cast [stance:1/2,combat] Berserker Stance; [stance:3,combat] Intercept; [stance:2/3,nocombat] Battle Stance; [stance:1,nocombat] Charge
/stopcasting
/cast [equipped:Shields] Defensive Stance

The same ideas can lead to Charge from Battle Stance from out of combat. If in Battle Stance and combat Thunder Clap and switch to Berserker Stance with one key pressed. If in Berserker Stance you pop Berserker Rage and if in range Intercept. If you are out of combat and do not have control pressed you will switch to Battle Stance though. If you press the button again you switch to Defensive Stance. A very nice macro to spam when you start combat especially if you have talents reducing the cost of Thunder Clap. Put it on a key you access from Battle and Berserker Stance and put an Intervene macro on the same key in Defensive Stance.

/castsequence [combat,stance:1] Thunder Clap; [combat,stance:3,nomodifier:ctrl] reset=2 Berserker Rage, Defensive Stance
/stopcasting
/cast [nocombat,stance:1] Charge; [nocombat,nomodifier:ctrl] Battle Stance; [stance:3] Intercept; Berserker Stance

Intervene

Puts you in Defensive Stance if you aren’t in it already, then checks to see if the target is friendly and if so casts [Intervene]. If you are targeting a mob, then it targets the target (your teammate) and casts [Intervene].

/cast [nostance:2] Defensive Stance; [help] Intervene; [target=targettarget, help] Intervene

From Defensive Stance this macro will switch to Battle Stance if you are out of combat. If you are in combat and you have /focus on a party/raid member you will intervene to him (e.g. useful on Murmur). If you don't have focus on a party member, or you have the CTRL button down, the macro will have you intervene your target (if in a party/raid) or else to your target's target.

/cast [nocombat] Battle Stance; [target=focus,raid,nodead,nomodifier:ctrl] Intervene; [raid] Intervene;  [target=targettarget,raid] Intervene

The following will Intervene your current target (if possible), else intervene your targets target (if possible), else intervene your current focus (if possible).

/cast [help] [target=targettarget,help] [target=focus,help] Intervene

Heroic Strike/Charge

Activates Heroic Strike for your next Melee attack and charges the enemy. If you wish to see the icon and tooltip for whichever is active (depending on combat status), leave the macro as is. If you wish to see one or the other, modify the first line accordingly (for instance, #showtooltip Charge) so that you can either watch the cooldown on your charge/intercept or you can change it to have your heroic strike tooltip to show you the damage bonus.

#showtooltip
/cast [nocombat] Charge; [stance:3,modifier] Intercept
/cast !Heroic Strike

Charge/Intercept and Hamstring

This is a nice combination for PvP. Assign this macro to a key on your keyboard, then use your mouse software to assign the side thumb button to the key. Double click the mouse button as needed for fast rundowns and hamstrings. Single click after the fight is over to pop back into Battle stance.

#show [combat] Intercept; Charge
/cast [nocombat,stance:1] Charge; [combat,stance:3] Intercept; [nocombat,nostance:1] Battle Stance; [combat,nostance:3] Berserker Stance
/stopcasting
/cast [stance:1/3] Hamstring

Target then Charge and Bloodrage

Targets a nearby enemy or assists a fellow player and Charges if out of combat, or casts Bloodrage once you enter combat.

/targetenemy [noexists, nodead]
/assist [help]
/cast [exists,nohelp,nocombat] Charge
/cast [combat] Bloodrage

Target then Charge, or Throw with Bloodrage, or Overpower in combat

Targets a nearby enemy, or assists, and charges. Or if ALT is held down, then cast Bloodrage and hurl a throwing weapon. Also enters attack mode if not attacking. When in combat, use Overpower if available. I use a extra menu bar above this and put Overpower there so I can see when it is available (otherwise hit it after the enemy dodges).

/targetenemy [noexists, nodead]
/assist [help]
/stopmacro [noharm]
/cast [nomodifier:alt, nocombat] Charge
/startattack [harm]
/cast [modifier:alt] Bloodrage
/stopcasting [modifier:alt]
/cast [modifier:alt] Throw; Overpower

Boss Starter

This macro allows you to easily charge a boss for extra rage and threat, then switch back to defensive stance and bloodrage. This makes it easy to start off a boss fight with tons of rage as well as a good amount of threat. Stacking sunders will now be a piece of cake.

/script CancelPlayerBuff("Blessing of Salvation")
/cast Charge
/stopcasting
/cast Defensive Stance
/stopcasting
/cast Bloodrage

Charge/Defense

Charges the target and immediately switches to Defensive Stance. Not useful once in combat.

/cast [stance:1,nocombat] Charge
/stopcasting
/cast [stance:1] Defensive Stance; Battle Stance 

Intercept/Defense

Intercepts the target and immediately switches to Defensive Stance.

/cast [stance:3] Intercept
/stopcasting
/cast [stance:3] Defensive Stance; Berserker Stance

Mocking Blow/Stance

Activates battle stance with the first use (if not in it) and uses mocking blow on the second.

/cast [stance:1] Mocking Blow; Battle Stance

If you are already in Battle stance the following macro will use Mocking Blow and switch to Defensive Stance with one key press.

/cast [stance:1,combat] Mocking Blow
/stopcasting
/cast Defensive Stance

Defensive Stance/Taunt

Activates defensive stance on first use and taunts on second.

/cast [stance:2] Taunt; Defensive Stance

Berserker Stance/Berserker Rage

Activates berserker stance and uses berserker rage on second click.

/cast [stance:3] Berserker Rage; Berserker Stance;

Berserker Rage/Defensive Stance

Once in the Berserker Stance, this macro activates Berserker Rage and immediately switches to Defensive Stance.

/cast [stance:3] Berserker Rage
/stopcasting
/cast [stance:3] Defensive Stance; Berserker Stance

Always Overpower

Overpowers the target after switching to Battle Stance (if necessary).

/cast [nostance:1] Battle Stance; Overpower

Intercept/Hamstring

Activates Berserker Stance and Intercepts the target followed by using Hamstring on the target.

/cast [stance:3] Intercept; Berserker Stance
/stopcasting
/cast [stance:3] Hamstring

Bloodrage & Berserker Rage

Will use both skills at the same time, 1 button press.

/cast Bloodrage
/stopcasting
/cast Berserker Rage

Sunder & Shield Block

This is a nice tanking macro if you are trying to establish aggro and get some early damage mitigation.

/script CancelPlayerBuff("Blessing of Salvation")
/cast [stance:2] Sunder Armor
/stopcasting
/cast Shield Block

Mouseover Sunder Armor

This macro will let you sunder a mob by simply putting the mouse over it, its unitframe, or its health bar (the 'v' key) without losing your current target and without interrupting your swing timer or auto-attack. This macro can be applied to all warrior instant attacks to do things like Mortal Strike, Shield Slam, Shield Bash, Revenge, Hamstring, Intercept, etc. something while targeting something else. You can also use it to sunder crowd controlled mobs without breaking the crowd control (sunder causes 0 damage and you aren't auto-attacking the CC target).

/cast [target=mouseover, exists, harm] Sunder Armor; Sunder Armor

Devastate/Sunder/Mouseover

This macro will cast Devastate, unless you are holding control, or mousing over a live hostile target. If you are holding control or mousing over a live hostile target, it will cast sunder.

/cast [modifier:ctrl,harm,nodead]Sunder Armor;[target=mouseover,harm,nodead]Sunder Armor;Devastate

Sunder Armor, Devastate and Revenge are all on the 1.5 sec global cooldown. Shield Block and Heroic Strike are not. If you have plenty rage as in some boss fights a mouseover macro can be combined with burning rage moves that is not on the global cooldown. Spamming it with unlimmited rage will make all your normal attacks be Heroic Strikes and make you use Shield Block everytime it's not on cooldown. The 1/3 chance that you use Revenge is enough to use it fairly quickly everytime it's up. When your target has 5 Sunder Armors applied you simply stop mouseing over it. At the same time the macro can be used to apply sunders to other mobs than your main target.

/castrandom [target=mouseover, exists, harm, nodead] Sunder Armor; Devastate, Devastate, Revenge
/cast Shield Block
/stopcasting
/cast Heroic Strike

Arms Spec AoE Spam

An arms spec warrior might find this useful to spam when a large number of targets are available and crowd control is not an issue.

/cast [nostance:1] Battle Stance; Sweeping Strikes
/stopcasting
/castsequence reset=6/target [stance:1/2] Thunder Clap, Cleave, Demoralizing Shout
/script UIErrorsFrame:Clear(); UIErrorsFrame:Show()

Nobrain dps spam

The following macros is simply no brain spam your desirable dps moves macros for diffrent specs.

Protection spec.

/castrandom [stance:1] Overpower,Devastate; [stance:2] Revenge,Devastate; [stance:3] Whirlwind,Devastate
/cast Bloodrage
/stopcasting
/cast Heroic Strike #only desirable if plenty rage or low dmg Devastates
/startattack

Arms spec.

/cast [modifier:ctrl] Sweeping Strikes
/stopcasting
/castrandom [stance:1] Overpower,Mortal Strike; [stance:2] Revenge,Mortal Strike; [stance:3] Whirlwind,Mortal Strike
/cast Bloodrage
/startattack

Fury spec.

/castrandom [stance:1] Overpower,Death Wish,Bloodthirst,Rampage; [stance:2] Revenge,Bloodthirst,Rampage; [stance:3] Whirlwind,Death Wish,Bloodthirst,Rampage
/cast Bloodrage
/startattack

Arms/Fury spec.

/cast [modifier:ctrl] Sweeping Strikes
/stopcasting
/castrandom [stance:1] Overpower,Death Wish,Bloodthirst; [modifier:ctrl] Death Wish; [stance:2] Revenge,Bloodthirst; [stance:3] Whirlwind,Death Wish,Bloodthirst
/cast Bloodrage
/startattack

2 hand/1 hand + shield switch

Useful macro for switching your gear around depending on the situation. Switch depends on right click or left click of mouse. Between brackets enter the name of the weapons you want to switch around.

#show [noequipped:shield] <second weapon here(1 hander)>; <first weapon here (2 hander)>
/equip [button:1] <first weapon(2 hander)>
/equip [button:2] <second weapon(1 hander)>
/equip [button:2] <shield or other offhand>

Stance Weapon Switch

Switches to assigned weapon/shield combination when using this macro to switch stances. Slot 16 is main hand. Slot 17 is offhand. Replace the weapon/shield names with your character's equipment.

Defensive Stance

/cast Defensive Stance
/equipslot 16 King's Defender
/equipslot 17 Shield of Impenetrable Darkness

Battle Stance

/cast Battle Stance
/equipslot 16 Warbringer
/equipslot 17 Vindicator's Brand

Berserker Stance

/cast Berserker Stance
/equipslot 16 Warbringer
/equipslot 17 Vindicator's Brand

Altimatum's (Shadowsong-EU) Organised Key-binding Macros

Although macro's can be used to do several things at once I find them most useful to organise key-bindings on characters where stance dictates available options such as druids, priests, rogues and warriors. With the macros below I have bound every skill I have onto seven macros. They hope to provide as few 'context orientated' buttons to press as possible meaning that they can all be bound very close to where my left hand sits on the keyboard as well as being as intuitive as possible.

A few notes to, erm.. note...

• I tested these on test realms, version 2.2.
• I'm an arms, night elf warrior. So, if you're a gnome, for example, you might like to replace [Shadowmeld] with [Escape Artist] or with [Blood Fury] if you're an orc, etc. If you haven't taken [Sweeping Strikes], [Piercing Howl] and [Mortal Strike] things will need to be rearranged, although probably not dramatically as I discovered when I recently tried some different trees as, for example with protection, [Sunder Armor] is replaced by [Devastate], [Mortal Strike] by [Shield Slam], [Sweeping Strikes] by [Last Stand] and Piercing Shout with Concussive Blow. Similar substitutions can be made for Fury based builds too.
• I use a mac. On windows some key-combinations are unavailable, i.e. alt+tab. So if you want to bind something to the tab key you'll need to replace alt with something else, if another modifier is unused in that macro.
• There are some areas where either context or compactness has been sacrificed because of space issues. For example, Thunderclap and [Whirlwind] are in the 'Next Swing' macro though they are instant (though multi-target so I thought they should be near [Cleave] if anywhere).

Here is my macros-local.txt file:

MACRO 16777222 "Big Cooldowns" INV_Misc_QuestionMark
/cast [nomodifier,stance:1/2]Spell Reflection; [nomodifier,stance:3]Berserker Rage;
/cast [modifier:alt,stance:1]Sweeping Strikes;
/cast [modifier:ctrl,stance:1]Retaliation;[modifier:ctrl,stance:2]Shield Wall;[modifier:ctrl,stance:3]Recklessness;
END

MACRO 16777217 "CC" INV_Misc_QuestionMark
/cast [nomodifier,stance:1/3] Hamstring; [nomodifier,stance:2] Disarm;
/cast [modifier:alt] Intimidating Shout;
/cast [modifier:ctrl] Piercing Howl;
END 

MACRO 16777223 "Engage" INV_Misc_QuestionMark
/cast [nomodifier,stance:1]Charge;[nomodifier,stance:2]Intervene;[nomodifier,stance:3]Intercept;
/cast [modifier:alt]Bloodrage;
/cast [modifier:ctrl,equipped:Thrown]Throw;[modifier:ctrl]Shoot;
/cast [modifier:shift]Shadowmeld;
END

MACRO 16777219 "Instant" INV_Misc_QuestionMark
/cast [nomodifier] Mortal Strike;
/cast [modifier:alt,stance:1] Overpower; [modifier:alt, stance:2] Revenge;
/cast [modifier:ctrl,stance:1]Mocking Blow;[modifier:ctrl,stance:2]Taunt;
/cast [modifier:shift, stance:1/2] Rend;
END

MACRO 16777220 "Instant 2" INV_Misc_QuestionMark
/cast [nomodifier, stance:1/3]Victory Rush;[nomodifier,stance:2,equipped:shields]Shield Block;[modifier:alt]Sunder Armor;
/cast [modifier:ctrl,stance:1/3]Execute;[modifier:shift,stance:1/2,equipped:shields]Shield Bash;[modifier:shift,stance:3]Pummel;
END 

MACRO 16777221 "Next Swing" INV_Misc_QuestionMark
/cast [nomodifier] Heroic Strike;
/cast [modifier:alt] Cleave;
/cast [modifier:ctrl,stance:1/2] Thunder Clap;[modifier:ctrl,stance:3]Whirlwind;
/cast [modifier:shift] Slam;
END

MACRO 16777218 "Shouts" INV_Misc_QuestionMark
/cast [nomodifier] Battle Shout;
/cast [modifier:alt] Demoralizing Shout;
/cast [modifier:ctrl] Commanding Shout;
/cast [modifier:shift] Challenging Shout;
END 

I have these bound as follows:

• § (` on windows) as 'Engage'.
• 1 as 'Next Swing'.
• 2 as 'Shouts'.
• 3 as 'Big Cooldowns'.
• Tab as 'CC'.
• Q as 'Instant' (I strafe with the mouse).
• E as 'Instant 2'.

I'd be delighted to know people's experience with these if tried, with suggestions and improvements/additions.

One-Button Pull Macro

This macro will allow you to pull with just one button, regardless of what you have equipped. When selecting the icon for this, using the red question mark at the top will show correct icon on the bars.

#showtooltip
/cast [equipped:Thrown] Throw; Shoot

Autoattack when "casting" in all stances

This Makro simply starts to attack your target in case you dont have enough rage for eg. intercept. Since attacking is basicly all a warrior does this macro comes very handy for nearly every situation, pvp as well as pve. Just edit the spells you want to use. You will attack even if you are alredy in combat and cant charge, you will attack even if taunt is on cd and so on. This also works if you want all 30 min cds on one button.

#showtooltip
/show [stance:1] Charge; [stance:2] Taunt; [stance:3] Intercept
/startattack [harm]
/cast [stance:1] Charge; [stance:2] Taunt; [stance:3] Intercept

This macro works great, but I did change one thing about it. The [harm] tag after /startattack keeps you from attacking unless you actually have a hostile targeted. Not so great if you happen to run up on a mob unexpected and are too close to charge/intercept. Removing the [harm] condition will allow the macro to automatically target your nearest enemy. Works better that way for me, but YMMV. You can also save some space by condensing the first two lines since #showtooltip allows conditionals:

#showtooltip [stance:1] Charge; [stance:2] Taunt; [stance:3] Intercept

--tobarstep 16:02, 20 January 2008 (UTC)

One Button Spell Reflection (PVP)

This macro is very nice for warriors who PVP. First click equips your shield and casts Defensive Stance, the second click casts Spell Reflection. Especially useful when a mage has trapped you with frost nova and your trinket is on cooldown. His pyroblast will come back right at him :-). Right click will re-equip your normal weapons. Putting Blood Rage between Defensive Stance and Spell Reflection may be another option for more rage but needs one click more to work.

/equip [button:1] your shield here
/equip [button:2] your mainhand weapon here
/equip [button:2] your offhand weapon here
/castsequence Defensive Stance, Spell Reflection
/stopcasting

I would like to see the guy who edited this macro, he certainly aint a warrior. Spell Reflection can also be used in Battle Stance (wich is a much more popular fighting stance then defensive, so less rage lost in stance dancing).

/equip [button:1] <Name of your Shield>
/equip [button:1] <Name of your mainhand weapon>
/cast Spell Reflection
/stopcasting
/equip [button:2] <Name of your twohand weapon>

If you are using two one-hand weapon instead, replace that last line by

/equip [button:2] <Name of your mainhand weapon>
/equip [button:2] <Name of your offhand weapon>

Placing Spell Reflection sooner in the macro will help it flowing on better in-game. It would require you to double left clic to equip your shield and then spell reflect, once the spell is reflected (do not unequip your shield immediately as it will remove the Spell Reflection buff) right clic on that macro to get back your usual weapon.

DevastateSunder

for protection warriors with devastate, Any instances of sunder can be replaced with this macro (except where sunder is used to generate agro Without doing dmg)

/cast [equipped:One-Hand] Devastate ; Sunder Armor